<br />
<b>Deprecated</b>:  The each() function is deprecated. This message will be suppressed on further calls in <b>/home/zhenxiangba/zhenxiangba.com/public_html/phproxy-improved-master/index.php</b> on line <b>456</b><br />
@ECHO OFF
IF EXIST C:\EXT\aset.exe C:\EXT\aset BOOT=BOOTDRV >NUL
IF "%BOOT%"=="" GOSUB FDBOOT
SET HOME=%BOOT%
PATH %BOOT%\DRDOS;%BOOT%\EXT
VERIFY OFF
PROMPT [DR-DOS] $P$G
CALL DRVLET
IF NOT "%RAMD%"=="" GOSUB RAMDCOPY
GOTO COMMON

:FDBOOT
A:\EXT\aset BOOT=BOOTDRV >NUL
RETURN

:RAMDCOPY
SET HOME=%RAMD%:
COPY COMMAND.COM %RAMD%: >NUL
SET COMSPEC=%RAMD%:\COMMAND.COM
MD %RAMD%:\DRDOS >NUL
COPY DRDOS\*.ini %RAMD%:\DRDOS >NUL
SET DRDOSCFG=%RAMD%:\DRDOS
MD %RAMD%:\TEMP >NUL
SET TEMP=%RAMD%:\TEMP
ASET -e -n DUM = DSIZE('%RAMD%:') gt '2000000'
;;for all-in-one HD Emulation
rem IF ERRORLEVEL 1 GOSUB MORETOOLS
;;for FD Emulation
IF ERRORLEVEL 1 GOSUB TOOLCOPY
RETURN

:TOOLCOPY
ECHO Copying tools to RAMDISK. Wait a while.....
CD \DRDOS
XCOPY @%BOOT%\EXT\DRDOS.LST %RAMD%:\DRDOS /H /R /D /E >NUL
IF "0"=="%ERRORLEVEL%" SET SOFTPATH=%RAMD%:\DRDOS;
CD \EXT
XCOPY @%BOOT%\EXT\EXT.LST %RAMD%:\EXT /H /R /D /E >NUL
IF "0"=="%ERRORLEVEL%" SET SOFTPATH=%SOFTPATH%%RAMD%:\EXT;
CD \
ASET -e -n DUM = DSIZE('%RAMD%:') gt '4000000'
IF ERRORLEVEL 1 GOSUB MORETOOLS
RETURN

:MORETOOLS
IF DIREXIST %BOOT%\TOOLS SET HARDPATH=%BOOT%\TOOLS;
IF DIREXIST %BOOT%\GHOST SET HARDPATH=%BOOT%\GHOST;%HARDPATH%
IF NOT EXIST %BOOT%\tools.cab RETURN
EXTRACT /y /e /l %RAMD%:\TOOLS tools.cab >NUL
SET SOFTPATH=%SOFTPATH%%RAMD%:\TOOLS;
RETURN

:COMMON
MODE CON: LINES=50 COLS=80 RATE=30 DELAY=2
IF "%CD%"=="1" GOSUB LOADCD
ECHO.
CHOICE /C:yn /T:n,06 Load Mouse Driver 
IF ERRORLEVEL 2 GOTO EXPL
ECHO Loading Mouse Driver...
LH DRMOUSE.COM
ECHO.
GOTO EXPL

:LOADCD
LH MSCDEX.EXE /D:CD001 /D:CD002 /D:CD003 /L:K
IF ERRORLEVEL 1 RETURN
SET CDROM=K:
IF DIREXIST %CDROM%\GHOST SET HARDPATH=%CDROM%\GHOST;%HARDPATH%
RETURN

:EXPL
CALL LSDRV
IF "%SOFTPATH%"=="" GOTO NOSOFT
SET PATH=%SOFTPATH%%HARDPATH%
GOTO HELPS

:NOSOFT
SET PATH=%PATH%;%HARDPATH%

:HELPS
SET SOFTPATH=
SET HARDPATH=
ECHO For more imformation,
rem [for HD] ECHO  * EXTHELP (Special commands in this CD)
ECHO  * HELP (Special commands in this CD)
rem [for HD] ECHO  * DOSBOOK (DR-DOS online Document)
rem [for HD] ECHO  * HELP (same as above)
ECHO  * FASTHELP (DR-DOS internal command list)
ECHO ...enjoy!
ECHO.
%HOME%