1. Home » 
2. エクセル練習問題：目次 » 
3. 合計と平均の計算

エクセル練習問題：合計と平均の計算

更新:2025/9/13;作成:2012/4/20

問題1の解答例　　　　topへ

• 問題1：E列と6行目の各合計を求めなさい。
• 解答
  

  	B	C	D	E
  2	商品	上半期	下半期	合計
  3	りんご	5,800	2,790	8,590
  4	みかん	4,580	4,680	9,260
  5	バナナ	7,540	7,720	15,260
  6	合計	17,920	15,190	33,110

• オートサムで一気に合計する

  1. 合計するセルと合計を表示するセルを含めて選択します。←ここがポイント
     C3:E6セルを選択します。
     
  2. オートSUMのショートカットキー [Altl]+[Shift]+[=]　を押します。
     • [ホーム]タブの[オートサム(Σ)]ボタンをクリックします。
       
       または、数式タブの[オートSUM]ボタンをクリックします。
       
  3. 合計が計算されました。
     
     • セルに桁区切りが表示されないときは、[ホーム]タブの数値グループにある「桁区切りスタイルを適用します。
       

数式の例

• 	B	C	D	E
  2	商品	上半期	下半期	合計
  3	りんご	5,800	2,790	=SUM(C3:D3)
  4	みかん	4,580	4,680	=SUM(C4:D5)
  5	バナナ	7,540	7,720	=SUM(C5:D5)
  6	合計	=SUM(C3:C5)	=SUM(D3:D5)	=SUM(C6:D6)

  • SUM関数、オートサムの説明は　SUM関数　もご覧ください。
• 最新の関数を使って計算した例(記:2025/9/13)
  E3セルには　=BYROW(C3:D5,SUM)
  C6セルには　=BYCOL(C3:E5,SUM)
  と入力しています。
  
  • BYROW,BYCOL関数の使い方は　BYROW関数とBYCOL関数を使った例 をご覧ください。
  

問題2　　　topへ

• 問題2：E列と6行目の各平均を求めなさい。　　問題2の解答

  	B	C	D	E
  2	商品	上半期	下半期	平均
  3	りんご	5,800	2,790
  4	みかん	4,580	4,680
  5	バナナ	7,540	7,720
  6	平均

問題2の解答例　　　　topへ

オートSUMを使って一気に平均する

1. C3:E6セルを選択します。
   
2. [ホーム]タブの[オートサム(Σ)]ボタンの[▼]をクリックして[平均]をクリックします。
   アクセスキーは　[Alt][H][U][A]と順番にキーをたたきます。
   
3. 平均の数式が入力され、計算結果が表示されます。
   
   • 桁区切りスタイルが適用されていないときは、[ホーム]タブの[桁区切りスタイル]をクリックします。
     

数式の例

• 数式の例
  

  	B	C	D	E
  2	商品	上半期	下半期	平均
  3	りんご	5,800	2,790	=AVERAGE(C3:D3)
  4	みかん	4,580	4,680	=AVERAGE(C4:D4)
  5	バナナ	7,540	7,720	=AVERAGE(C5:D5)
  6	平均	=AVERAGE(C3:C5)	=AVERAGE(D3:D5)	=AVERAGE(C6:D6)

  • AVERAGE関数の説明は　AVERAGE関数　をご覧ください。
• 最新の関数を使って計算した例(記:2025/9/13)
  E3セルには　=BYROW(C3:D5,AVERAGE)
  C6セルには　=BYCOL(C3:E5,AVERAGE)
  と入力しています。
  
  • BYROW,BYCOL関数の使い方は　BYROW関数とBYCOL関数を使った例 をご覧ください。
  

問題3　　　topへ

• 問題3：E:F列と6:7行目の各合計と平均を求めなさい。　　問題3の解答
  

  	B	C	D	E
  2	商品	上半期	下半期	合計	平均
  3	りんご	5,800	2,790
  4	みかん	4,580	4,680
  5	バナナ	7,540	7,720
  6	合計
  7	平均

問題3の解答例　　　　topへ

• 	B	C	D	E	F
  2	商品	上半期	下半期	合計	平均
  3	りんご	5,800	2,790	8,590	4,295
  4	みかん	4,580	4,680	9,260	4,630
  5	バナナ	7,540	7,720	15,260	7,630
  6	合計	17,920	15,190	33,110	16,555
  7	平均	5,973	5,063	11,037	5,518

• 数式の例
  

  	B	C	D	E	F
  2	商品	上半期	下半期	合計	平均
  3	りんご	5,800	2,790	=SUM(C3:D3)	=AVERAGE(C3:D3)
  4	みかん	4,580	4,680	=SUM(C4:D4)	=AVERAGE(C4:D4)
  5	バナナ	7,540	7,720	=SUM(C5:D5)	=AVERAGE(C5:D5)
  6	合計	=SUM(C3:C5)	=SUM(D3:D5)	=SUM(C6:D6)	=AVERAGE(C6:D6)
  7	平均	=AVERAGE(C3:C5)	=AVERAGE(D3:D5)	=AVERAGE(E3:E5)	=AVERAGE(C7:D7)

1. C3:E6セルを選択します。
   
2. オートSUMのショートカットキー [Alt]+[Shift]+[=]　を押します。
   • または、[ホーム]タブの[オートサム(Σ)]ボタンをクリックします。
     
3. これで合計の数式は入力できました。
   
4. 平均を求める F3:F6セルを選択します。
   
5. F3セルに =ave　と入力すると、数式オートコンプリートの機能でaveが含まれる関数がドロップダウンリストに表示されます。
   [↓]キーを押して、AVERAGE　を選択します。
   [Tab]キーを押すとAVERAGE関数が入力されます。
   
6. セル範囲C3:D3セルをドラッグして選択して、数式を　=AVERAGE(C3:D3) にします。
   
7. [Ctrl]+[Enter]で数式を確定します。
   選択していたセル F3:F6に一気に数式が入力されます。
   
   • F3セルのみに数式を入力した場合は、F3セルのフィルハンドルをF6セルまでドラッグまたはダブルクリックして、数式と書式をコピーします。
     
8. C7:F7セルを選択します。
   C7セルに　=AVERAGE(C3:C5) と入力して、[Ctrl]+[Enter]で数式を一気に入力します。
   
   • C7セルに =AVERAGE(C3:C5)　と入力した場合は、F7セルまでオートフィルでコピーします。
     

問題4　　　topへ

• 問題4：F4とF7に売り上げ上位3人、売り上げの下位3人の売り上げの平均を求めなさい。　　問題4の解答
  

  	B	C	D	E	F
  2	No	氏名	売上	順位
  3	1	矢鍋 日出夫	4,412	8	売り上げ上位3人の平均売上
  4	2	中元 英寿	5,378	7
  5	3	松山 利香	7,069	3
  6	4	大江 政勝	5,850	5	売り上げ下位3人の平均売上
  7	5	羽田 弘吉	5,491	6
  8	6	飯尾 雅文	1,129	10
  9	7	井上 達也	7,161	2
  10	8	勝谷 隆一	4,409	9
  11	9	鶴岡 和男	6,903	4
  12	10	西崎 敬次	7,959	1

問題4の解答例　　　　topへ

FILTER関数を使って求める

• Excel for Microsoft 365,Excel2021以降ではFILTER関数が使用できます。
  FILTER関数の使い方は　FILTER関数でデータを抽出する:Excel関数　をご覧ください。
• 売り上げ上位3位は　RANK.EQ(D3:D12,D3:D12)<=3)　で求めました。
  FILTER関数を使って、上位3位までの売上を配列に取り出し、AVERAGE関数で平均しています。
  F4セルに　=AVERAGE(FILTER(D3:D12,RANK.EQ(D3:D12,D3:D12)<=3))
  
• 売り上げ下位3位は　RANK.EQ(D3:D12,D3:D12,1)<=3)　で求めました。
  FILTER関数を使って、下位3位より小さい売上を配列に取り出し、AVERAGE関数で平均しています。
  F7セルに　=AVERAGE(FILTER(D3:D12,RANK.EQ(D3:D12,D3:D12,1)<=3))　と入力します。
  

AVERAGE関数とLARGE関数、SMALL関数で求める

• 売上の多い3つのデータはLARGE(D3:D12,{1,2,3})、売り上げの少ない3つのデータはSMALL(D3:D12,{1,2,3})　で得ることができます。
  この得られた3つの値をAVERAGE関数で平均しています。
  

  	B	C	D	E	F
  2	No	氏名	売上	順位
  3	1	矢鍋 日出夫	4,412	8	売り上げ上位3人の平均売上
  4	2	中元 英寿	5,378	7	=AVERAGE(LARGE(D3:D12,{1,2,3}))
  5	3	松山 利香	7,069	3
  6	4	大江 政勝	5,850	5	売り上げ下位3人の平均売上
  7	5	羽田 弘吉	5,491	6	=AVERAGE(SMALL(D3:D12,{1,2,3}))
  8	6	飯尾 雅文	1,129	10
  9	7	井上 達也	7,161	2
  10	8	勝谷 隆一	4,409	9
  11	9	鶴岡 和男	6,903	4
  12	10	西崎 敬次	7,959	1

• 下図は、F4セルを選択して、数式バーで　LARGE(D3:D12,{1,2,3})　を選択して、[F9]を押した状態です。
  解除して元の数式に戻すには[Esc]キーを押します。
  LARGE(D3:D12,{1,2,3})→{7959,7161,7069}　となっています。　売り上げの多い3つのデータが配列で得ることができたのが分かります。
  

AVERAGEIF関数で求める

• この問題では、E列に順位が計算されていますので、この順位を利用することができます。
  AVERAGEIF関数で、「売り上げ上位3人の平均売上」は順位が3以下の平均で求めることができます。
  「売り上げ下位3人の平均売上」は順位が8以上の平均で求めることができます。
  • AVERAGEIF関数はExcel2007で追加された関数です。　AVERAGEIF関数　をご覧ください。
  F3セルは =AVERAGEIF(E3:E12,"<=3",D3:D12)、F7セルは =AVERAGEIF(E3:E12,">=8",D3:D12)　と入力します。
  

  	B	C	D	E	F
  2	No	氏名	売上	順位
  3	1	矢鍋 日出夫	4,412	8	売り上げ上位3人の平均売上
  4	2	中元 英寿	5,378	7	=AVERAGEIF(E3:E12,"<=3",D3:D12)
  5	3	松山 利香	7,069	3
  6	4	大江 政勝	5,850	5	売り上げ下位3人の平均売上
  7	5	羽田 弘吉	5,491	6	=AVERAGEIF(E3:E12,">=8",D3:D12)
  8	6	飯尾 雅文	1,129	10
  9	7	井上 達也	7,161	2
  10	8	勝谷 隆一	4,409	9
  11	9	鶴岡 和男	6,903	4
  12	10	西崎 敬次	7,959	1

• AVERAGEIF関数の引数のダイアログボックスを使う場合は、範囲に E3:E12　、条件に　"<=3"　、平均対象範囲に　D3:D12　と入力します。
  

AVERAGE関数とIF関数で求める(配列数式で求める)

• AVERAGEIF関数が使えないExcel2003以前では配列数式で求めることができます。
• F4セルに、=AVERAGE(IF(E3:E12<=3,D3:D12))　と入力して、[Ctrl]+[Shift]+[Enter]で数式の入力を確定します。
  なお、Excel2021以降の動的配列数式を使えるバージョンではそのままの入力で計算できます。
  

問題5　　　topへ

• 問題5：下表の小計と総計を求めなさい。　　　問題5の解答
  ここでは、D列はSUM関数で、E列はSUBTOTAL関数で、F列はAGGREGATE関数で小計と総計を求めなさい。
  なお、F8セルには　=NA() と入力して　エラー値 #N/A を返しています。
  

  	B	C	D	E	F
  2	種類	商品	1月	2月	3月
  3	果物	みかん	6,764	5,888	6,287
  4		りんご	7,959	8,028	7,546
  5		バナナ	4,629	4,696	3,944
  6		小計
  7	野菜	大根	2,888	1,916	3,805
  8		キャベツ	3,045	3,702	#N/A
  9		白菜	7,256	7,634	7,607
  10		小計
  11	肉	牛肉	7,405	8,446	7,950
  12		豚肉	4,253	3,148	3,372
  13		鶏肉	5,865	4,777	7,466
  14		小計
  15	総計

問題5の解答例　　　　topへ

• 
• 数式は下図のようになります。
  

  	B	C	D	E	F
  2	種類	商品	1月	2月	3月
  3	果物	みかん	6,764	5,888	6,287
  4		りんご	7,959	8,028	7,546
  5		バナナ	4,629	4,696	3,944
  6		小計	=SUM(D3:D5)	=SUBTOTAL(9,E3:E5)	=AGGREGATE(9,2,F3:F5)
  7	野菜	大根	2,888	1,916	3,805
  8		キャベツ	3,045	3,702	=NA()
  9		白菜	7,256	7,634	7,607
  10		小計	=SUM(D7:D9)	=SUBTOTAL(9,E7:E9)	=AGGREGATE(9,2,F7:F9)
  11	肉	牛肉	7,405	8,446	7,950
  12		豚肉	4,253	3,148	3,372
  13		鶏肉	5,865	4,777	7,466
  14		小計	=SUM(D11:D13)	=SUBTOTAL(9,E11:E13)	=AGGREGATE(9,2,F11:F13)
  15	総計		=SUM(D14,D10,D6)	=SUBTOTAL(9,E3:E14)	=AGGREGATE(9,2,F3:F14)

• SUBTOTAL関数やAGGREGATE関数の詳細な使い方は　小計の関数(SUBTOTAL関数)の使い方 ,AGGREGATE関数の使い方 をご覧ください。

オートサム機能を使って SUM関数を入力する

1. D3:D6セルを選択します。
   
2. [Ctrl]キーを押した状態で、C7:C10、C11:C14、C15セルを選択します。
   
3. オートSUMのショートカットキーは　[Alt]+[Shift]+[=] です
   • または、[ホーム]タブの[オートSUM]ボタンをクリックします。
     
4. D6セルには　=SUM(D3:D5)、D10セルには　=SUM(D7:D9)、D14セルには =SUM(D11:D13) 、D15セル =SUM(D14,D10,D6) と SUM関数の数式が入力されました。
   ここでは、[数式]タブの[数式の表示]をクリックして、数式を表示しています。
   

SUBTOTAL関数の数式の入力方法

1. E6セルを選択して、=sub　と入力します。
   subを含む関数がドロップダウンリストに表示されます。
   [↓]キーを押して　SUBTOTALを選択して、[Tab]キーを押します。
   
2. =SUBTOTAL(と入力されます。
   引数の集計方法がリストに表示されます。[↓]キーを押して、「9-SUM」を選択して、[Tab]キーを押します。
   
3. =SUBTOTAL(9　と入力されます。
   カンマを入力し、引数の参照範囲を入力します。
   =SUBTOTAL(9,E3:E5)　とします。
   
4. E6セルを選択して、[ホーム]タブの[コピー]をクリックします。ショートカットキーは [Ctrl]+[C]です。
   E10セルを選択し、[Ctrl]キーを押した状態でE14セルも選択します。
   [ホーム]タブの[貼り付け]→[数式]をクリックして、E6セルの数式をE10とE14セルに数式をコピーします。
   
5. E15セルには =SUBTOTAL(9,E3:E14) と入力します。
   

AGGREGATE関数の数式の入力方法（SUBTOTAL関数と同様なので詳細は省略します）

• AGGREGATE関数の引数ダイアログで、集計方法は 9 、オプションは 2、参照1に　F3:F5 と入力します。
  オプションで 2 を指定すると、エラー値を無視することができます。
  

スポンサードリンク

PageViewCounter

Since2006/2/27