1. Home » 
2. エクセル関数の技 » 
3. 日付のセルの個数をカウントする

日付のセルの個数をカウントする:Excel関数の技

• 同じ日付が入力されたセルの個数(数)や同じ月の日付をカウントする方法を説明しています 。
  月ごとの日付のセル数をカウントする方法を説明しています。

更新:2025/4/2;作成2016/1/13

同じ日付が入力されたセルの個数(数)をカウントする　　topへ

• 下表のようなデータから同じ日付が入力されたセルの個数をカウントします。
  

  	B	C
  2	日付	数量
  3	2024/6/14	79
  4	2024/6/15	61
  5	2024/6/16	37
  6	2024/6/17	65
  7	2024/6/20	65
  8	2024/6/13	55
  9	2024/6/14	53
  10	2024/6/15	61
  11	2024/6/16	67
  12	2024/6/17	60
  13	2024/6/20	55
  14	2024/6/14	76
  15	2024/6/15	47

• [問題1]B列の日付に　2024/6/15　と入力されているセルの数をカウントしなさい。
• [解答例]セルの数を数えるにはCOUNTIF関数が使えます。
  =COUNTIF(B3:B15,"2024/6/15")
  =COUNTIF(B3:B15,DATE(2024,6,15))
  で求めるのが一般的だと思います。
  COUNTIF関数の引数の検索条件はExcelが日付と認識できればよいので、以下のように日本語の形式でも使うこともできます。
  =COUNTIF(B3:B15,"2024年6月15日")
  =COUNTIF(B3:B15,"令和6年6月15日")
  または、2024/6/15 のシリアル値　45458　を使っても計算できます。
  =COUNTIF(B3:B15,45458)
  =COUNTIF(B3:B15,"R6.6.15")
  =COUNTIF(B3:B15,"R6-6-15")
• ただし、数式の入力のしやすさからは上記の　
  =COUNTIF(B3:B15,"2024/6/15")　
  といった形が一般的と言えると思います。
  

• [問題２]B列の日付の数をカウントしなさい。ただし、重複している日付は１個として数えます。
• [解答例]重複していない日付をUNIQUE関数で求め、COUNT関数でその数を数えます。
  E2セルに　=SORT(UNIQUE(B3:B15))　と入力しています。
  重複しない日付が表示されます。
  これらの日付を数えるには COUNT関数を使います。
  E12セルに　=COUNT(UNIQUE(B3:B15))　と入力して、「6」と答えが出ました。
  

日付が入力されたセルの個数(数)を条件付きでカウントする　　topへ

• 下表のようなデータから 6月の日付が入力されたセルの個数をカウントします。
  

  	B	C
  2	日付	数量
  3	2024/5/14	61
  4	2024/5/20	33
  5	2024/5/26	55
  6	2024/6/1	62
  7	2024/6/7	48
  8	2024/6/13	41
  9	2024/6/19	61
  10	2024/6/25	42
  11	2024/7/1	65
  12	2024/7/7	49
  13	2024/7/13	39
  14	2024/7/19	45
  15	2024/7/25	53

COUNTIF関数またはCOUNTIFS関数で求める

• Excel2007以降では、COUNTIFS関数を使って複数の条件を設定して求めることができます。
  日付が 2024/6/1以上　から　2024/7/1未満　　と条件を指定すればよいので、
  =COUNTIFS(B3:B15,">=2024/6/1",B3:B15,"<2024/7/1")　となります。
• Excel2003以前では、COUNTIF関数を使うことになります。
  2024/6/1以上から　2024/7/1以上の数を差し引けばよいことになります。
  数式は　=COUNTIF(B3:B15,">=2024/6/1")-COUNTIF(B3:B15,">=2024/7/1")　となります。
• 

SUMPRODUCT関数で求める

• MONTH関数を使って、月が「6」であるセルをカウントすることもできます。
  数式は　=SUMPRODUCT((MONTH(B3:B15)=6)*1)　とします。
  SUMPRODUCT関数の使い方は　SUMPRODUCT関数の使い方:Excel関数　をご覧ください。
  

FILTER関数を使って求める

• Excel for Microsoft 365,Excel2021ではFILTER関数を使うことができます。
  FILTER関数の詳細は　FILTER関数でデータを抽出する　をご覧ください。
• FILTER関数を使って、該当する月のデータを配列に抽出して、COUNT関数でカウントします。
  数式は　=COUNT(FILTER(B3:B15,MONTH(B3:B15)=6))　としています。　
  該当する月が複数年あるときは、TEXT関数で年と月まで抽出条件を指定します。
  数式は　=COUNT(FILTER(B3:B15,TEXT(B3:B15,"yyyy/m")="2024/6"))　としました。
  • TEXT(B3:B15,"yyyymm")="202406"　としてもOKです。
  

• 関連するページ
  
  • カウント(COUNT)の関数の使い方
  • 条件に一致するセルをカウントする(COUNTIF関数,COUNTIFS関数)
  • SUMPRODUCT関数の使い方

スポンサードリンク

　PageViewCounter
　
　Since2006/2/27