1. Home » 
2. エクセル関数一覧表 » 
3. Excel関数の目次 » 
4. Excel関数の目次 » 
5. 数学/三角関数の使い方

数学/三角関数(ABS,PI,SINなど)の使い方:Excel関数

• エクセルの数学・三角関数の使い方を例を挙げて説明しています。

更新:2025/1/18;作成:2006/4/20

数値の絶対値を返します　　　topへ
　アブソルート
=ABS(数値)
数値から符号 (+ -) を除いた数値の絶対値を返します。

• 【問題】値Aと値Bの差を求めなさい。
  

  	B	C	D
  2	値A	値B	差
  3	10	5	5
  4	5	10	5

• 【解答例】
  差を求めるので、計算式は　B3-C3　となります。
  差の絶対値を求めるので、　=ABS(B3-C3)　としました。
  絶対値記号を使った数式は　=|B3-C3|　と書きますので、絶対値マークを ABS関数に置き換えて、=ABS(B3-C3)　となります。

  	B	C	D
  2	値A	値B	差
  3	10	5	=ABS(B3-C3)
  4	5	10	=ABS(B4-C4)

  
  =ABS(5-10)=ABS(-5)　は「5」と正の値になります。

数値の正負を調べます　　　topへ
　サイン
=SIGN(数値)
数値が正の数のときは 1、0 のときは 0、負の数のときは -1 となります。

• 【問題1】下期は上期に対し値が「向上」「下落」「同じ」のいずれかを表示しなさい。
  

  	B	C	D
  2	上期	下期	傾向
  3	100	80	下落
  4	85	97	向上
  5	90	90	同じ

• 【解答例】
  C3-B3　の値が　正の値、0、負の値　のいずれかになるかを調べます。
  IF関数を使って、負の値の時「下降」と表示し、正の値の時「向上」と表示し、それ以外は「同じ」と表示するようにします。
  負の値とは　SIGN(C3-B3)=-1　、正の値とは SIGN(C3-B3)=1　の時になります。
  
  D3セルに　=IF(SIGN(C3-B3)=-1,"下落",IF(SIGN(C3-B3)=1,"向上","同じ"))　と入力します。
  
• 【別解】
  D3セルに　=CHOOSE(SIGN(C3-B3)+2,"下落","同じ","向上")　として下方向へコピーします。
  SIGN(C3-B3)で-1,0,1が返されるので、+2とすると、1,2,3になります。
  これをCHOOSE関数のインデックスとして利用します。
  
  SIGN関数を使わず、TEXT関数の表示形式を利用することもできます。
  D3セルに　=TEXT(C3-B3,"向上;下落；同じ")　として下方向へコピーします。

円周率πを返す　　　topへ
　パイ
=PI()
　円周率3.14159265358979 を返します。この数値の精度は 15 桁です。

• 【問題】半径 5cmの円の面積を求めなさい。
• 【解答】
  円の面積は円周率×半径×半径　「円周率×(半径の2乗)」　で求められます。
  下図のケースでは　=PI()*B3^2　または　=PI()*B3*B3　とします。
  • べき乗には　キャレット ^　を使います。日本語キーボードでは「へ」が印刷されているキーです。
  小数以下2桁で丸める場合(四捨五入)は ROUND関数と組み合わせます。
  

角度(度数)をラジアンに変換する
　ラジアン
=RADIANS(角度)

ラジアンを度数に変換する
　ディグリーズ
=DEGREES(ラジアン)

角度のsinを返す
　サイン
=SIN(ラジアン)

角度のcosを返す
　コサイン
=COS(ラジアン)

角度のtanを返す
　タンジェント
=TAN(ラジアン)

• 度数とラジアン
  

  度数	0°	90°	180°	360°
  ラジアン	0	π/2	π	2π

• 角度が30度の場合のcos,sin,tanを求めてみましょう。
  

  cos30°	0.866025404	=COS(PI()/6)
  sin30°	0.5	=SIN(PI()/6)
  tan30°	0.577350269	=TAN(PI()/6)

• 度数を直接使うには、RADINA関数を使ってラジアンに直して計算します。
  

  cos30°	0.866025404	=COS(RADIANS(30))
  sin30°	0.5	=SIN(RADIANS(30))
  tan30°	0.577350269	=TAN(RADIANS(30))

sin,cosカーブを書いてみます

1. A2セルに=SEQUENCE(700,,0)と入力て、セル範囲 A2:A699に 0〜699 の整数値を入力します。
2. B2に　=SIN(RADIANS(A2))　
   C2に　=COS(RADIANS(A2))　と入力します。
   B2:C2を選択した状態で、フィルハンドルをダブルクリックします。
   すると、B2:C701まで数式が入力され、sin(0)〜sin(699)　と cos(0)〜cos(699)の値が求められます。
3. A1:C701を選択します。
   [挿入]タブのグラフグループにある[散布図]→[散布図(平滑線)]を実行します。
   
4. 下図のように、sinカーブ,cosカーブを作成することができました。
   

直角三角形を使った三角関数の概念

平方根を返す　　　topへ
　スクエア
=SQRT(数値)
数値に負の数を指定すると、エラー値 #NUM! が返されます。

• ルート(√)の計算に使います。　=SQRT(4)=2　となります。
• 数値が負の数になるとエラーになるので、絶対値を返すABS関数と組み合わせて、=SQRT(ABS(数値)) のようにすることもあります。
• 【他の計算式】
  • 算術演算子(^)を使った例：=4＾(1/2)　　=4＾0.5
  • POWER関数を使った例：=POWER(4,1/2)　　=POWER(4,0.5)

べき乗を返す　　　topへ
　パワー
=POWER(数値,指数)

• 数値の指数乗を返します。　2の2乗なら、=POWER(2,2)=4　となります。
  
• 【他の計算式】
  • =2^2　と算術演算子「^」(キャレット)を使っても計算できます。

積を返す　　　topへ
　プロダクト
=PRODUCT(数値1,数値2)

• 引数に指定した数値または範囲の積を返します。
• 数値だけが計算の対象となり、配列または参照に含まれる空白セル、論理値、および文字列はすべて無視されます(1として計算されます)。
• 四則演算の積(*)と同じ計算ができます。
  • PRODUCT関数が四則演算の積(*)と異なるのは、引数に空白（B4セル)、文字列(B5セル)、論理値(B6,B7セル)の時は無視され「1」として計算されます。
    空白のセルがある時は四則演算では「0」となりますが、PRODUCT関数を使うと「1」とみなして計算されます。(4行目の説明)
  

eのべき乗を返す　　　topへ
　イクスポネンシャル
=EXP(数値)

• e を底とする数値のべき乗を返します。
• 定数 e は自然対数の底で、e=2.71828182845904

指定された数を底とする数値の対数を返す　　　topへ
　ログ
=LOG(数値,底)

• 底：省略すると、10 を指定したと見なされます

10を底とする数値の対数を返す　　　topへ
　ログ テン
=LOG10(数値)

• 10を底とする数値の対数(常用対数)を返します

自然対数を返す　　　topへ
　ログ ナチュラル(ロン)
=LN(数値)

• 自然対数とは、定数 e (2.71828182845904) を底とする対数のことです
• EXP関数の逆数になります。

指定された基数 (底) のテキスト表現に、数値を変換する　　　　topへ
　ベース
=BASE(数値, 基数 [Min_length])
　Excel2013で追加された関数です。

• BASE(数値, 基数 [Min_length])
  • 指定された基数 (底) のテキスト表現に、数値を変換します。
  • 下図の例はA列の値をB列に2進数で表記しています。C列は8進数の表記です。
  

階乗を返す　　　topへ
　ファクトリアル
=FACT(数値)

• 数値の階乗を返します。数値の階乗は、1〜数値の範囲にある整数の積です。
• 数値に整数以外の値を指定すると、小数点以下が切り捨てられます。
  A2セルの 4.8 の場合は小数点以下を切り捨てて、4の階乗を求めます。（B2セル）
• 数値に負の数を指定すると、エラー値 #NUM! が返されます。 （B3セル）
• 0（ゼロ）の階乗は 1 と定義されています。（B4セル）

• (使用例)　B2セルの説明　=FACT(4)=4*3*2*1=24となります。
  

スポンサードリンク

PageViewCounter

Since2006/2/27