1. Home » 
2. エクセル関数一覧表 » 
3. Excel関数の目次 » 
4. データベース関数の使い方

データベース関数の使い方:Excel関数

• エクセルのデータベース関数(DSUM関数,DAVERAGE関数,DCOUNT関数,DMAX関数,DMIN関数,DGET関数)の使い方を解説しています。
• これらのワークシート関数の特徴は条件をフィールドに書き出す必要があることです。

更新:2025/10/13;作成:2003/4/12

Excelのバージョンに注意が必要です。(Excel2002以外の場合の注意点)

• 検索条件の書き方に注意が必要なケースがあります。このページではDGET関数で例示して説明しています。
• 文字列の検索を行うと、部分一致で検索されます(Excel2002だけが完全一致で検索されます)
  • 検索条件(Criteria)として文字列を入力すると、その文字列ではじまるアイテムがすべて検索されます。
  • たとえば、検索条件として「岡」と入力すると、"岡本"、"岡田"、"岡崎" などが検索されます。
• 指定した文字列に完全に一致するアイテムだけを検索するには、次に示す数式を入力します。
  • ="=文字列" :[文字列]に検索する文字列を入力します。
  • (参考)
    • データベース関数での注意点も一度ご覧ください。
    • [XL2002]複雑な検索条件を使用してリストデータを抽出する方法
      http://support.microsoft.com/KB/402757/JP

合計を求める
　ディー サム
=DSUM(Database,フィールド,Criteria)

平均値を求める
　ディー アベレージ
=DAVERAGE(Database,フィールド,Criteria)

数値が入力されているセルの個数を求める
　ディー カウント
=DCOUNT(Database,フィールド,Criteria)
　　DCOUNT関数,DCOUNTA関数はカウントの関数(複数条件でのカウント)で説明しています。

最大値を求める
　ディー マックス
=DMAX(Database,フィールド,Criteria)

最小値を求める
　ディー ミン
=DMIN(Database,フィールド,Criteria)

ポイント：条件（Criteria)の書き方が重要　　同一行はAND　別の行はORになります。

AND条件での条件の設定と計算式

• 【問題1】2025年のデータ表(B2:E15）から、2025年4月分の「りんご」「M」サイズの販売個数に関して合計などを求めなさい。
  条件をG3:J3へ、計算式をH6:H10に入れなさい。
  

  	B	C	D	E	F	G	H	I	J
  2	期日	商品名	サイズ	販売個数		期日	期日	商品名	サイズ
  3	2025/3/1	りんご	M	10
  4	2025/3/1	みかん	M	30
  5	2025/4/1	りんご	M	11		販売個数
  6	2025/4/1	みかん	L	20		合計	36
  7	2025/4/2	りんご	M	12		平均	12
  8	2025/4/2	みかん	M	30		セルの数	3
  9	2025/4/2	りんご	L	40		最大値	13
  10	2025/4/3	みかん	M	30		最小値	11
  11	2025/4/3	りんご	M	13
  12	2025/5/1	みかん	M	30
  13	2025/5/1	みかん	L	20
  14	2025/5/2	りんご	L	40
  15	2025/5/2	りんご	M	14

【問題1の解答例】

• 期日が4月ですので、「>=2025/4/1」「<2025/5/1」のAND条件になります。
  G2:J3の4列2行を使用して条件を書きます。 AND条件は同一行に書きます。
  データベース関数を使い分ければOK です。
  関数が異なるだけで、引数は同一です。
  

【別解1】DSUMの例で示します。

• フィールドに列見出しを用いる例
  • =DSUM(B2:E15,"販売個数",G2:J3)
• フィールドに列位置の番号を用いる例 ：販売個数の列はデータリストで左から4番目です。
  • =DSUM(B2:E15,4,G2:J3)

【別解2】

• 引数の条件を論理式で指定することもできます
  K2セルは空欄のままにするか、下図のようにフィールド名と異なる文字列「条件」と入力します。
  K3セルには　=AND(MONTH(B3)=4,C3="りんご",D3="M")　と入力しています。（データの先頭行をデータの代表とみなして数式を作成しています。）
  セルには「FALSE」と表示されます。
  • =AND(B3>=DATE(2025,4,1),B3<DATE(2025,5,1),C3="りんご",D3="M")　とすることもできます。
  =DSUM(B2:E15,E2,K2:K3)　←CriteriaにはK2セルを含めて指定していることに注意してください
• 引数のフィールドの書き方もいろいろあります。
  DSUM関数の例です。
  =DSUM(B2:E15,E2,K2:K3)
  =DSUM(B2:E15,"販売個数",K2:K3)
  =DSUM(B2:E15,4,K2:K3)
  • 下図ではK2セルにフィールド名と異なる文字列「条件」と入力しています。
    空欄としていてもよいのですがこちらの方が見た目が良いかもしれません。
  

OR条件の場合

• 【問題2】「りんご」「M」サイズと「みかん」「M」サイズの販売個数に関して合計などを求めなさい。
  条件をG3:H4へ、計算式をH6:H10に入れなさい。

• 	B	C	D	E	F	G	H	I
  2	期日	商品名	サイズ	販売個数		商品名	サイズ
  3	2025/3/1	りんご	M	10
  4	2025/3/1	みかん	M	30
  5	2025/4/1	りんご	M	11		販売個数
  6	2025/4/1	みかん	L	20		合計	180
  7	2025/4/2	りんご	M	12		平均	20
  8	2025/4/2	みかん	M	30		セルの数	9
  9	2025/4/2	りんご	L	40		最大値	30
  10	2025/4/3	みかん	M	30		最小値	10
  11	2025/4/3	りんご	M	13
  12	2025/5/1	みかん	M	30
  13	2025/5/1	みかん	L	20
  14	2025/5/2	りんご	L	40
  15	2025/5/2	りんご	M	14

【問題2の解答例】

• OR条件になるので、2行に分けて条件を書きます。
  • 【商品名が「りんご」かつ(AND) サイズが「M」】
    または(OR)【商品名が「みかん」かつ(AND)　サイズが「M」】の販売個数を求めることになります。
  

【別解2】条件を数式で表す例

• I2は空欄のまま、I3に=OR(AND(C3="りんご",D3="M"),AND(C3="みかん",D3="M"))とすれば、
  =DSUM(B2:E15,E2,I2:I3)　となります。
  I3セルの数式は　=AND(OR(C3="りんご",C3="みかん"),D3="M")　とすることもできます。
  

値を取り出す
　ディー ゲット
=DGET(Database,フィールド,Criteria)

• このDGET関数はCriteria(検索条件)を満たす1つの値を返します。
  Criteria(検索条件)を満たすレコードがない場合は、エラー値 #VALUE! が返されます。
  Criteriaを満たすレコードが複数存在する場合は、エラー値 #NUM! が返されます。
• VLOOKUP関数やINDEX関数と似ていますが、抽出条件をセルで指定すること、抽出のキーとなる列が左端になくてもよいことが異なっています。

• 【例】下表のC14セルの値と一致するデータを取り出すことができます。

  • CritriaはC13:C14に設定しています。C14の氏名を変更すると、国語〜合計の値が変化します。
  • D14に=DGET($B$2:$H$11,D13,$C$13:$C$14)と入力して、H14までコピーします。
  • D14セルの計算式　=DGET($B$2:$H$11,D13,$C$13:$C$14)
    E14セルの計算式　=DGET($B$2:$H$11,E13,$C$13:$C$14)
    F14セルの計算式　=DGET($B$2:$H$11,F13,$C$13:$C$14)
    G14セルの計算式　=DGET($B$2:$H$11,G13,$C$13:$C$14)
    H14セルの計算式　=DGET($B$2:$H$11,H13,$C$13:$C$14)
  • 取り出すときのフィールドの順番は関係ありませんので、下図のような取り出し方もできます。
    • 2行目のフィールド名と13行目のフィールド名が一致する箇所を取り出していますので、並び順は関係ありません。
      数式(計算式)は上と同じです。
      D14セルの計算式　=DGET($B$2:$H$11,D13,$C$13:$C$14)
      E14セルの計算式　=DGET($B$2:$H$11,E13,$C$13:$C$14)
      F14セルの計算式　=DGET($B$2:$H$11,F13,$C$13:$C$14)
      G14セルの計算式　=DGET($B$2:$H$11,G13,$C$13:$C$14)
      H14セルの計算式　=DGET($B$2:$H$11,H13,$C$13:$C$14)
    
  • Criteria(検索条件)の書き方の注意点
    • 文字列を検索条件にするときは前方一致で検索されますので注意が必要です。
      会田さんを条件にしたいとき　会　と指定することで検索できてしまいます。
      
    • ところが「会田川」さんがこの表に有ったら、答え(該当する解)が2つあることになり、#NUM!エラーとなります。
      会田 で始まる氏名が検索されるためです(前方一致)。
      
    • 「会田」を検索するには　「="=会田"」と入力する必要があります。(この方法で完全一致での検索ができます。)
      

スポンサードリンク

PageViewCounter

Since2006/2/27