<br />
<b>Deprecated</b>:  The each() function is deprecated. This message will be suppressed on further calls in <b>/home/zhenxiangba/zhenxiangba.com/public_html/phproxy-improved-master/index.php</b> on line <b>456</b><br />
;;; sc-init.el --- Supercite init file

;; Copyright (C) 1999,2000 YAMASHITA Junji

;; Author: YAMASHITA Junji <ysjj@unixuser.org>
;; Keywords: init, citation
;; Version: $Id: sc-init.el,v 1.6 2002/01/08 06:25:24 ysjj Exp $
;; Content-Type: text/plain; charset=iso-2022-jp

;;; Commentary:

;;; Code:

;;; Option Variables:
(setq sc-citation-leader "")
(setq sc-mode-map-prefix "\C-z\C-c")

(setq sc-auto-fill-region-p nil)

(setq sc-preferred-header-style 0)
(setq sc-rewrite-header-list
      '((my-sc-rewrite-header-simple) (my-sc-rewrite-header)))

;;;
(defun my-sc-rewrite-header-simple ()
  "supercite header rewrite function (simple version)."
  (let* ((sc-mumble "")
	 (from (sc-whofrom))
	 (name (sc-attribs-extract-namestring from))
	 (addr (sc-attribs-<>-addresses from))
	 (tag sc-reference-tag-string))
    (when from
      (let ((attr (sc-hdr "" (sc-mail-field "sc-attribution") "")))
	(insert (concat tag
			(if attr (concat attr " == "))
			(if (> (length name) 0) name addr)
			" wrote:\n"))))))

(defun my-sc-rewrite-header ()
  "supercite header rewrite function."
  (let ((sc-mumble "")
	(from (sc-whofrom))
	(tag sc-reference-tag-string))
    (when from
      (let ((date (sc-hdr "" (sc-mail-field "date") ""))
	    (subject (sc-hdr "" (sc-mail-field "subject") ""))
	    (attr (sc-hdr "" (sc-mail-field "sc-attribution") "")))
	(insert (concat tag date " の刻に\n"
			tag "Subject: " subject "\n"
			tag "において " from " 氏 曰く\n"
			(if attr
			    (concat tag "(以下 " attr " == " from ")\n"))))))))

;;; working with BBDB.
(bbdb-insinuate-sc)

(let ((attrs (member "x-attribution" sc-preferred-attribution-list)))
  (setcdr attrs `("sc-consult" ,@(cdr attrs))))

(setq sc-attrib-selection-list
      (append sc-attrib-selection-list
	      '(("sc-from-address"
		 ((".*" . (bbdb/sc-consult-attr
			   (sc-mail-field "sc-from-address"))))))))

(let ((empty-line-frame (assoc "^$" sc-mail-glom-frame)))
  (setcdr empty-line-frame
	  `((progn (bbdb/sc-default)
		   ,(cadr empty-line-frame)))))


;;; sc-init.el ends here